Reading Lines from Text file (Anonymous Monk)

Re: Reading Lines from Text file

Corion

created: 2006-02-02 11:31:47

perlmonks

prlmnks

I guess the secret to it is in skipping the things in the middle.

Read lines
...
Profit!

Re^2: Reading Lines from Text file

suaveant

created: 2006-02-02 11:38:28

perlmonks

prlmnks

Or the George Costanza approach...

1. Open the file
2. yadda yadda yadda
3. First and last line.

- Ant
- Some of my best work - (1 2 3)

Re^3: Reading Lines from Text file

Fletch

created: 2006-02-02 11:49:23

perlmonks

prlmnks

"You yadda'd the best part!"

"No, I told you about opening the file."

*Cue scene change bass riff*

Re: Reading Lines from Text file

ikegami

created: 2006-02-02 11:53:42

perlmonks

prlmnks

my $first;
my $last;

{
   open(my $fh, '<', 'file')
      or die("Unable to open input file: $!\n");

   while (<$fh>) {
      $first = $_ if not defined $first;
      $last  = $_;
   }
}

or

use File::ReadBackwards ();

my $first;
my $last;

{
   open(my $fh, '<', 'file')
      or die("Unable to open input file: $!\n");

   $first = <$fh>;
}

{
   my $fh = File::ReadBackwards->new('file')
      or die("Unable to open input file: $!\n");

   $last = $fh->readline();
}

or

my $first;
my $last;

{
   open(my $fh, '<', 'file')
      or die("Unable to open input file: $!\n");

   ($first, $last) = (<$fh>)[0, -1];
}

Re: Reading Lines from Text file

malduarte

created: 2006-02-02 12:44:52

perlmonks

prlmnks

This is a good example of a simple question which can have complex answers depending of the circumstances....

Small files:

perl -e "@l = <>; print 'first : ', $l[0], 'last  : ', $l[$#l];" filename

This approach is only recommended for small files because all the lines are being read to an array (copying everything to memory before printing the lines)

Medium sized files:
```
perl -e "$first = <>; while($line = <>) { $last = $line; }; print 'first : ', $first, 'last  : ', $last;" filename
```
This approach is recommended for medium sized files because it's reading one line at a time into memory.
It's still not recommended for larges files because the entire file is being read. If you have a 4gbyte file and your I/O subsystem is only able to read 10 Mbytes/second you're going to take 400 seconds to get the answer.

Really large files
For really large files you can read the first line normally (see above). To read the last line, you have to:
- seek to the end of the file
- search for the line terminator of the line before the last
- read from the position of the character after the line terminator to the end of file.
I'm sorry for not providing a working example, but I don't have my script library with me right now. You can allways read the Unix command tail source code for inspiration :-)

Re^2: Reading Lines from Text file

holli

created: 2006-02-02 14:48:50

perlmonks

prlmnks

seek to the end of the file

search for the line terminator of the line before the last

read from the position of the character after the line terminator to the end of file.

Or use File::ReadBackwards as ikegami suggests.

holli, /regexed monk/

Re: Reading Lines from Text file

zshzn

created: 2006-02-02 13:18:53

perlmonks

prlmnks

And then of course there is the lazy, unportable solution.

my $first  = `head -1 $filename`;
my $second = `tail -1 $filename`;

If you happened to want a solution regardless of the implementation (ie Perl or not), and were ignorant of the head and tail programs, then learn to use those.

Re^2: Reading Lines from Text file

holli

created: 2006-02-02 14:44:42

perlmonks

prlmnks

Why unportable? There are versions of "tail" and "head" for various OSses.

holli, /regexed monk/

Re^3: Reading Lines from Text file

malduarte

created: 2006-02-02 18:00:34

perlmonks

prlmnks

Even if there are versions available for other OSses:

not every tail and head accept the same set of arguments
you may not have a compiler available to compile new tools
you may not able to install new software on the machine you're working,
Since you're using backticks, you're relying on whatever shell you have available, environment variables, aliases, (...)

The safest way is to rely only on the Perl interpreter.

Re^2: Reading Lines from Text file

graff

created: 2006-02-02 21:50:50

perlmonks

prlmnks

Or, if you don't mind a little less portability in order to do one less sub-shell invocation:

my ( $first, $last ) = `head -1 $filename && tail -1 $filename`;