I will agree that there's a distinct difference between "trivial" and "not too difficult" that applies to converting between iterators and recursive solutions. However, jd and I found it easier to write recursive solutions, so there's a trade-off in difficulty: It might be easier en toto to come up with a recursive one and then convert it to an iterator.

Not even understanding [jdporter]'s algorithm, I converted it to be iterative (or perhaps more precisely, lazily evaluated). I made the derange function print only the first 15 results, for convenient testing of large inputs.

sub _derange_iter {
  my ($cb, $todo, @v) = @_;
  @$todo or return do { $cb->( @v ); sub {} }; # this line was wrong before
  my %seen;
  @seen{@v} = ();
  my ( $range, @todo ) = @$todo;
  my @sub_iter = map {
    my $my_ = $_;
    sub { _derange_iter ( $cb, \@todo, @v, $my_ ) }
  } grep { ! exists $seen{$_} } @$range;
  return sub {} unless (@sub_iter);
  # Grab and unwrap an iterator from the list
  my $iter = (shift @sub_iter)->();
  return sub {
      my $rval;
      $iter = (shift @sub_iter)->()
        until ($rval = $iter->() or @sub_iter == 0);
      return $rval;
  }
}

sub derange(&@)
{
    my $cb = shift;
    my $iter = _derange_iter( $cb,
        [ map { my $x = $_; [ grep { $_ ne $x } @_ ] } @_ ] );
    for (1..15) {
      $iter->();
    }
}

derange { print "@_\n" } @ARGV;

From enumerators to cursors: turning the left fold inside out...

The mechanical inversion procedure presented in * had a catch: it relies on shift/reset (or call/cc plus a mutable cell, which is the same thing). How can we do such an inversion in Haskell? We can introduce a right fold enumerator, which is more amenable to such transformations. Or we can use a continuation monad and emulate shift/reset. The present article demonstrates the third approach: a non-recursive left-fold. We argue that such a left fold is the best interface for a collection. Indeed, given the non-recursive left-fold we can:

• instantiate it into the ordinary left fold
• instantiate in into a stream

If we turn two enumerators into streams, we can *safely* interleave these streams.

We should point out that the relation between the left fold, the non-recursive left fold and the stream is deep. The ordinary, recursive left fold is the fix point of the non-recursive one. On the other hand, the instantiation of the non-recursive left fold as a stream, as we shall see, effectively captures a continuation in a monadic action. We see once again that call/cc and Y are indeed two sides of the same coin **.

The rest of the article demonstrates the inversion procedure. The procedure is generic, as evidenced by its polymorphic type. We illustrate the technique on an example of a file considered a collection of characters. Haskell provides a stream interface to that collection: hGetChar. We implement a left fold enumerator. We then turn that enumerator back to a stream: we implement a function 'myhgetchar' _only_ in terms of the left fold enumerator. The approach is general and uses no monadic heavy lifting.

Re^6: Derangements iterator (callbacks)

demerphq

created: 2006-01-02 07:33:49

perlmonks

• reply
• node
• thread
• author

• node
• author
• thread

prlmnks

• node
• thread
• author

Well, seeing as apparently you understand this article maybe you could give us an example how to turn foreach (@list){ ... } into a cursor based approach. Since perl doesnt support first class continuations I guess you will need to implement this "left fold" operator. Which in itself would be pretty interesting. Actually even explaining in normal english (unlike the functional jargon gobbly-gook that the article uses) what this "left fold" operator does would be nice.

---
$world=~s/war/peace/g

Re^7: Derangements iterator (callbacks)

Anonymous Monk

created: 2006-01-02 14:27:31

perlmonks

• reply
• node
• thread
• author

• node
• author
• thread

prlmnks

• node
• thread
• author

#!/usr/bin/perl -w

# A non-recursive left fold (foldl), taken from Language::Functional
sub foldl(&$$) {
  my($f, $z, $xs) = @_;
  map { $z = $f->($z, $_) } @{$xs};
  return $z;
}

# Recursive foldl
sub foldl_rec {
  my($f, $z, $xs) = @_;
  my($head, @tail) = @$xs;
  $head ? foldl_rec($f, $f->($z,$head), \@tail) : $z;
}

# "Fold" is the universal list traversal function. Also known as
# "reduce" (see List::Util) and "accumulate" (C++ STL).  Any function
# you write that munges lists (map, grep, etc.) can be rewritten in
# terms of a fold.  It essentially takes a list and replaces each "cons"
# constructor with a function.  Stated another way, if you have a list
# @a = (1, 2, 3, 4), fold will replace the commas with another function
# of your choosing.  Let's say you want the sum of the elements in @a.
# Replace the commas with a '+' sign, (1 + 2 + 3 + 4).  Easy isn't it?
# You might write it as...

$s = foldl(sub{ $_[0] + $_[1] }, 0, [1..4]);
print "sum = $s\n";  # 10

# ...in addition to providing the function and the list, you supply an
# initial value to start out with.  In the case of $sum above, we use
# 0.  If you want the product of the elements in the list you can change
# to...

$p = foldl(sub{ $_[0] * $_[1] }, 1, [1..4]);
print "product = $p\n";  # 24

# The "left" portion comes into play because we start at the left end of
# the list and work towards the right.  The actual sum that is
# calculated is (((((0+1)+2)+3)+4).  It only makes a difference when the
# function used isn't associative.  Subtraction is an example...


$l = foldl(sub{ $_[0] - $_[1] }, 0, [1..4]);
print "left fold subtraction = $l\n";  # ((((0-1)-2)-3)-4) == -10

# Recursive foldr
sub foldr_rec {
    my($f, $z, $xs) = @_;
    my($head, @tail) = @$xs;
    $head ? $f->($head,foldr_rec($f, $z, \@tail)) : $z;
}

$r = foldr_rec(sub{ $_[0] - $_[1] }, 0, [1..4]);
print "right fold subtraction = $r\n";  # (1-(2-(3-(4-0)))) == -2

# The dual of "fold" is the universal list creation function, "unfold".
# See more unfold in action...
#
#    http://use.perl.org/~Greg%20Buchholz/journal/26747 

Re^7: Derangements iterator (callbacks)

Anonymous Monk

created: 2006-01-14 14:33:35

perlmonks

• reply
• node
• thread
• author

• node
• author
• thread

prlmnks

• node
• thread
• author

Actually even explaining in normal english (unlike the functional jargon gobbly-gook that the article uses) what this "left fold" operator does would be nice.

Another explaination of the original paper.

Oops.. Sorry, the wrapper performs unnecessary operations, here a good version :

use Inline C => <<'END_OF_C_CODE';

void cderange ( SV* truc, ... ){
  SV* sv_temp;
  I32 index, i;
  Inline_Stack_Vars;

  srand(time( NULL ));
  index = Inline_Stack_Items;
  for (; index; index--) {
    i = (I32) (rand() % (index));
    sv_temp = Inline_Stack_Item(index);
    Inline_Stack_Item(index) = Inline_Stack_Item(i);
    Inline_Stack_Item(i) = sv_temp;
  }
  Inline_Stack_Done;
}

END_OF_C_CODE 

Very fast, but this code is subject to the same caveat as Algorithm::Numerical::Shuffle.

Here's a version you can add to Algorithm::Loops. It uses NestedLoops and is comparatively efficient about skipping invalid combinations. It also puts its results in numeric/lexicographic order and handles duplicates. The commented-out code is for watching/debugging the management of the "pool" of available numbers.

use strict;
use warnings;

use Algorithm::Loops 'NestedLoops';

sub derange {
  # Generate the list of possible values at each position
  # Skip a value if it's already used up (no more in the pool) or is in its original position
  my %pool;
  ++$pool{$_} for (@_);
  my @orig = @_;
  no warnings 'numeric';
  my @values = sort {$a <=> $b or $a cmp $b} keys %pool;
  my @prev_values;
  NestedLoops(
    [(sub {
        # Generate all candidate values for this position
# print "Generating with \@_ = @_\n";
        my $pos = @_;
        # Update the pool: the last value on @_ has just changed, so
        # return the previous value(s) to the pool and remove the new
        # one.
        if (@_) {
          for (grep {defined $prev_values[$_]} $#_..$#orig-1) {
#print "Returning $prev_values[$_] to the pool\n";
            ++$pool{$prev_values[$_]};
            undef $prev_values[$_];
          }
#print "Removing $_[-1] from the pool\n";
          --$pool{$_[-1]};
#print "Valid values in the pool:\n";
#while (my ($k,$v) = each %pool) {
#  print "$k: $v\n" if $v;
#}
          $prev_values[$#_] = $_[-1]; 
        }
        [ grep {$orig[$pos] ne $_ and $pool{$_} > 0} @values ]
      }) x @orig]
  );
}

my @results;
my $iter = derange(@ARGV);
print "@results\n" while @results = $iter->();

As a possibly interesting note: if you simply remove $orig[$pos] ne $_ and, it becomes a permutations generator. But derange is not simply a permutations generator that filters out individual invalid permutations; it prunes entire sub-trees. (Similarly, the permutation generator doesn't loop through the whole cartesian space and filter it.)